[info]bit 5-3 CHS2:CHS0: Analog Channel Select bits

000 = Channel 0 (AN0)   
001 = Channel 1 (AN1)   
010 = Channel 2 (AN2)   
011 = Channel 3 (AN3)   
100 = Channel 4 (AN4)   
101 = Channel 5 (AN5)   
110 = Channel 6 (AN6)   
111 = Channel 7 (AN7)    [/info]

Então eu posso fazer um laço para selecionar um por vez todos os caniais que vou utilizar e a cada passada eu já faço a conversão AD e vou mascarando de três em três bits até completar meu Byte para transmissão. Pode ser assim, não é?

Anderson,

Citação de: C N C N o w ! em 12 de Julho de 2010, 17:26

[info]bit 5-3 CHS2:CHS0: Analog Channel Select bits

000 = Channel 0 (AN0)   
001 = Channel 1 (AN1)   
010 = Channel 2 (AN2)   
011 = Channel 3 (AN3)   
100 = Channel 4 (AN4)   
101 = Channel 5 (AN5)   
110 = Channel 6 (AN6)   
111 = Channel 7 (AN7)    [/info]

Então eu posso fazer um laço para selecionar um por vez todos os caniais que vou utilizar e a cada passada eu já faço a conversão AD e vou mascarando de três em três bits até completar meu Byte para transmissão. Pode ser assim, não é?

Primeiramente, deve-se dividir o problema à "La Jack" (por partes)...

Eu faria desse jeito:

(1) Ler todas as entradas (analógicas e digitais)
(2) Enviar todos os sinais via porta serial

Isso garante que o tempo entre leituras será mínimo e o estado do sistema (joystick, chaves, ...) será amostrado de maneira completa a cada varredura.

O conversor A/D do PIC16F877A possui um tipo de "chave" interna (multiplexador) que a cada comando de leitura (instrução de escrita nos bits CHS0..CHS2 de ADDCON0), seleciona qual entrada do multiplexador (ou pino do microcontrolador) será amostrada e posteriormente convertida para o formato digital. Como a figura a seguir:

[attachthumb=1]

O sinal de saída do poteciômetro é conectado ao conversor A/D, de preferência, usando a mesma base de tensão de referência, mínima e máxima, para minimizar os erros. Normalmente se usa o +5 e 0V (GND), mas sendo talvez excessivamente purista, pode existir uma pequena discrepância entre o +5V do potenciômetro e o +Vref do conversor A/D. Sendo 5/256 = 19mV ou 5/1024 = 4,9mV, que seria a tolerância de erro do sistema. Como serão usadas apenas 7 faixas para cada potenciômetro e 256 níveis no conversor A/D, essa diferença seria desprezível e sem importância se a montagem possuir adequados filtros e desacoplamentos. Bem como ter cuidado em usar pontos comuns de aterramento (0V) e de alimentação (+5V) dos potenciômetros e do conversor A/D.

Mas por enquanto vamos pular essa parte.

O que o Jorge mandou vale a pena ler, sobre a tensão de referência, principalmente:

[attachthumb=1]

Melhorei o programa e a simulação, agora lê e envia tres entradas analógicas. O terminnal mostra o envio sequenciado de AN0 (0% = 0), AN1 (50%=7F) e AN2 (100%=FF).

[attachthumb=2]

Programa assembly:


    list P=16F877A
   #include "P16F877A.INC"

   __CONFIG _CP_OFF & _WDT_OFF & _XT_OSC & _PWRTE_ON
   ;__CONFIG 0x3F32

   errorlevel -302      ; turn off bank bits warning

;
; Seleção de entradas do MUX (ADDCON0)
;
#DEFINE  EAN_0 B'01000001'   ; f/8, AN0, DONE, A/D On
#DEFINE  EAN_1 B'01001001'   ; f/8, AN1, DONE, A/D On
#DEFINE  EAN_2 B'01010001'   ; f/8, AN2, DONE, A/D On
;
;   Variáveis da RAM internas
;   
   cblock H'20'
       ld_loop_ex
      ld_loop_in
    endc
;
; Inicio do Programa
;
   ORG   0h         

; Inicializaçao do PIC, do display e da porta serial
   bcf      STATUS,RP1

   bsf      STATUS,RP0 ; Habilita banco 1
   
   clrf   TRISD          ; porta do display, de saída
   
   movlw    B'00000010'    ; setup do conversor A/D
   movwf    ADCON1         ; left justify result
                     ; port A: only analogue inputs
;
; Ajusta parametros da UART (usando cristal externo de 4MHz)
; Baud Rate = 9600 bps, No Parity, 1 Stop Bit
;
    movlw    0x19             ; 0x19=9600 bps / 0x0C=19200 bps
    movwf    SPBRG
       
    movlw    b'00100100'     ; TX_Enable, assync. mode, brgh = high (2)
    movwf    TXSTA           ; enable Async Transmission, BRGH=1
   
    movlw    b'10111111'     ; RC6 saida, outros bits da PORTC sao de entrada
    movwf    TRISC

   bcf      STATUS,RP0       ; Habilita banco 0

   clrf   PORTD          ; zera saídas do display
   
;   movlw    EAN_0          ; seleciona entrada analógica
;   movwf    ADCON0          

    movlw    b'01000000'    ; Setup Port C
    movwf    PORTC         ; RC6(TX)=1 others are 0

    movlw    b'10000000'     ; habilita a UART
    movwf    RCSTA
;
; Loop principal
;
start:
   movlw    EAN_0          ; entrada analógica 0
   call   read_ad
   call   display
   call   send
   call   delay1s

   movlw    EAN_1          ; entrada analógica 1
   call   read_ad
   call   display
   call   send
   call   delay1s

   movlw    EAN_2          ; entrada analógica 2
   call   read_ad
   call   display
   call   send
   call   delay1s

   goto   start
;
; Conversor A/D, palavra ADDCON0 em W
;
read_ad:
   movwf   ADCON0
   bsf      ADCON0,GO ; Iniciar conversao
wait:
   btfsc    ADCON0,GO ; Testa se terminou conversao
   goto   wait
   movf   ADRESH,W
   return
;
; Display de LEDs
;
display:
   movwf   PORTD
   return
;
; Envia byte (contido em W) pela UART e espera terminar
;
send:
    movwf    TXREG           ; send data in W
TransWt:
    bsf    STATUS,RP0      ; banco 1
WtHere:
     btfss    TXSTA,TRMT      ; Transmissao terminou se TRUE
    goto    WtHere         ; Senao, espera
    bcf    STATUS,RP0      ; banco 0
    return
;
;-----------------------------------------------------------------------------
;
;   Delay for about 1s
;
delay1s:
    movlw   D'250'
   call   waitx400
    movlw   D'250'
   call   waitx400
    movlw   D'250'
   goto   waitx400

;
;-----------------------------------------------------------------------------
;
;   Delay for about 250 ms
;
delay250ms:
    movlw   D'250'
   goto   waitx400
;
;-----------------------------------------------------------------------------
;
;   Delay for about 400x cycles
;
;    Se w=1, temporiza 1ms @ fck = 4MHz
;
waitx400:
    movwf   ld_loop_ex
ld_loopex:
   movlw   (400-4)/4
   movwf   ld_loop_in
ld_loopin:
    decf    ld_loop_in,F
    skpz
    goto    ld_loopin
   decf    ld_loop_ex,F
    skpz
    goto    ld_loopex
   return

END

 

Vale a pena uma espiada:

Sim, posso usar no lugar do monitoramento da minha tensão, em substituição ao MC34164, não é mesmo ? Ainda não deu tempo de ler tudo, mas depois vou esmiuçar esse material. Grato

Melhorei o programa e a simulação, agora lê e envia tres entradas analógicas. O terminnal mostra o envio sequenciado de AN0 (0% = 0), AN1 (50%=7F) e AN2 (100%=FF).

Muito bom Gil, aos poucos vou acumulando material para aperfeiçoar o projeto. Eu carreguei o software e montei o circuito igual ao seu mas o resultado da simulação não ficou igual. Tem alguma configuração necessária no ISIS que eu não esteja cumprindo ?

minilathe

mestre ... me esclareça uma dúvida.
Quando se possui um equipamento que é alimentado por baterias, mas é necessário o monitoramento da tensão das baterias para que estas não sejam sugadas até o ponto de não ser recuperadas, vc acredita que é necessário ou que seja disperdício colocar uma bateria (tipo botão) apenas para referência de tensão? ou mesmo no caso de utilzar algum circuito que possuam aqueles DS1307 (RTC) e utilizar da bateria dele como referência de tensão para o microcontrolador ... isso é uma prática aceitável ou um disperdício?

abrax!